返回列表
发布日期: 2008-12-23 12:46 发布者: cobra Bookmark and Share 原版编程图书超低价热卖 1#
t T
赞助商
一. 相关说明：

    本篇将呈现完整的Flash Remoting访问远程服务器，包括以可视化组件方式和以编程方式访问远程服务器。Asp.net服务器端和Flex客户端完整代码下载。

二. 相关代码预览：

    1.frServices.as，以编程方式访问远程服务器。
  1. package com.demo.fr
  2. {
  3.     import flash.events.EventDispatcher;
  4.     import flash.net.NetConnection;
  5.     import flash.net.Responder;
  6.    
  7.     //用代码调用flash Remoting。
  8.     public class frServices
  9.     {
  10.         //Remoting服务器对象完整名称。
  11.         private var name_ServerClass : String = "Hxw.Demo.FlashRemoting.Hellow";
  12.         //初始化一个事件广播对象。
  13.         private var eventDispatcher : EventDispatcher = new EventDispatcher();       
  14.         //事件关键字定义：Event_KEY_Success_DisplayHellow。
  15.         public static var Event_KEY_Success_DisplayHellow : String = "Event_KEY_Success_DisplayHellow";
  16.         //事件关键字定义：Event_KEY_Success_SayHellowWorld。
  17.         public static var Event_KEY_Success_SayHellowWorld : String = "Event_KEY_Success_SayHellowWorld";
  18.         //事件关键字定义：Event_KEY_Success_GetUsers。
  19.         public static var Event_KEY_Success_GetUsers : String = "Event_KEY_Success_GetUsers";       
  20.         //事件关键字定义：Event_KEY_Fault。
  21.         public static var Event_KEY_Fault : String = "Event_KEY_Fault";           
  22.         //Remoting连接对象。
  23.         private var conn : NetConnection = null;
  24.         //Flash Remoting方法返回值获取对象。
  25.         private var rp :Responder = null;
  26.        
  27.         //构造器。
  28.         public function frServices()
  29.         {
  30.            
  31.         }
  32.        
  33.         //开始调用远程服务方法。
  34.         public function preCall(result : Function):void
  35.         {           
  36.             //初始化Remoting连接对象。
  37.             this.conn = new NetConnection();           
  38.             //调用connect( )方法，传递进Flash Remoting网关的URL。
  39.             this.conn.connect("http://localhost:5678/WebFR/Gateway.aspx");           

  41.             this.rp = new Responder(result,onError);   
  42.         }
  43.        
  44.         //调用远程服务方法。
  45.         public function call_DisplayHellow():void
  46.         {               
  47.             this.preCall(onResult_DisplayHellow);
  48.            
  49.             //对象的call( )方法调用Flash Remoting方法，call( )方法需要两个参数，
  50.             //第一个参数指定方法名称和路径，第二个参数指定响应处理函数，如果不需要处理函数，可直接设为null
  51.             //处理FlashRemoting响应。
  52.             this.conn.call(this.name_ServerClass + ".DisplayHellow",this.rp);
  53.         }
  54.        
  55.         //调用远程服务方法。
  56.         public function call_SayHellowWorld(name : String):void
  57.         {
  58.             this.preCall(onResult_SayHellowWorld);
  59.             this.conn.call(this.name_ServerClass + ".SayHellowWorld",this.rp,name);
  60.         }
  61.        
  62.         //调用远程服务方法。
  63.         public function call_GetUsers():void
  64.         {
  65.             this.preCall(onResult_GetUsers);
  66.             this.conn.call(this.name_ServerClass + ".GetUsers",this.rp);
  67.         }       
  68.        
  69.         //调用服务成功。
  70.         private function onResult_DisplayHellow(result : Object) : void
  71.         {
  72.             this.resultHandler(result,"DisplayHellow",frServices.Event_KEY_Success_DisplayHellow);
  73.         }
  74.        
  75.         private function onResult_SayHellowWorld(result : Object) : void
  76.         {
  77.             this.resultHandler(result,"SayHellowWorld",frServices.Event_KEY_Success_SayHellowWorld);
  78.         }
  79.        
  80.         private function onResult_GetUsers(result : Object) : void
  81.         {
  82.             this.resultHandler(result,"GetUsers",frServices.Event_KEY_Success_GetUsers);
  83.         }       
  84.        
  85.         //调用服务成功的处理。
  86.         private function resultHandler(result : Object,targetName : String ,eventKey : String) : void
  87.         {
  88.             var ce : CUEvent = new CUEvent(eventKey);
  89.             ce.Sender = result;
  90.             ce.CurrentTargetName = targetName;
  91.            
  92.             this.eventDispatcher.dispatchEvent(ce);
  93.         }
  94.        
  95.         //调用服务失败。
  96.         private function onError(error : Object):void
  97.         {
  98.             var ce : CUEvent = new CUEvent(Event_KEY_Fault);
  99.             ce.Sender = error;
  100.            
  101.             this.eventDispatcher.dispatchEvent(ce);   
  102.         }
  103.        
  104.         //创建一个供外部调用的附加事件侦听的方法。
  105.         public function addEventListener(type : String , listener : Function):void
  106.         {
  107.             this.eventDispatcher.addEventListener(type,listener);   
  108.         }

  110.     }
  111. }
复制代码
2.CUEvent.as，自定义事件。
  1. package com.demo.fr
  2. {
  3.     import flash.events.Event;
  4.    
  5.     //从Event继承一个类。
  6.     //为什么as3中仅仅能够定义一个构造器，郁闷。
  7.     public class CUEvent extends Event
  8.     {
  9.         //数据实体。
  10.         private var _sender : Object = null;
  11.         //方法名。
  12.         private var  _currentTargetName: String = "";
  13.        
  14.         //构造器(为什么as3中仅仅能够定义一个构造器，郁闷)。
  15.         public function CUEvent(type : String,bubbles : Boolean = false,cancelable : Boolean = false)
  16.         {
  17.             super(type,bubbles,cancelable);
  18.         }   
  19.        
  20.         //获取 数据实体。
  21.         public function get Sender():Object
  22.         {
  23.             return this._sender;
  24.         }

  26.         //设置 数据实体。
  27.         public function set Sender(value : Object) : void
  28.         {
  29.             this._sender = value;
  30.         }
  31.        
  32.         //获取 方法名称。
  33.         public function get CurrentTargetName() : String
  34.         {
  35.             return this._currentTargetName;
  36.         }
  37.        
  38.         //设置 方法名称。
  39.         public function set CurrentTargetName(value : String) :void
  40.         {
  41.             this._currentTargetName = value;
  42.         }

  44.     }
  45. }
复制代码
3.User.as，数据模型，对应服务器端的User.cs。
  1. package com.demo.fr
  2. {
  3.     [RemoteClass(alias="Hxw.Demo.FlashRemoting.User")]
  4.     public class User
  5.     {
  6.         public function User()
  7.         {
  8.         }
  9.        
  10.         private var _name : String = "";
  11.         private var _age : int = 0;
  12.         private var _sex : String = "";
  13.        
  14.         public function get Name():String
  15.         {
  16.             return this._name;
  17.         }
  18.        
  19.         public function set Name(v:String):void
  20.         {
  21.             this._name = v;
  22.         }
  23.        
  24.         public function get Age():int
  25.         {
  26.             return this._age;
  27.         }
  28.        
  29.         public function set Age(v:int):void
  30.         {
  31.             this._age = v;
  32.         }
  33.        
  34.         public function get Sex():String
  35.         {
  36.             return this._sex;
  37.         }
  38.        
  39.         public function set Sex(v:String):void
  40.         {
  41.             this._sex = v;
  42.         }
  43.        
  44.         public function toString():String
  45.         {
  46.             return "姓名：" + this._name + "；年龄：" + this._age.toString() + "；性别：" + this._sex;
  47.         }
  48.     }
  49. }
复制代码
4.MXML Application代码。
  1. <?xml version="1.0" encoding="utf-8"?>
  2. <mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">

  4.     <mx:Script>
  5.         <![CDATA[
  6.             import com.demo.fr.CUEvent;
  7.             import flash.net.navigateToURL;
  8.             import mx.collections.ArrayCollection;           
  9.             import mx.rpc.events.ResultEvent;
  10.             import mx.rpc.events.FaultEvent;
  11.             import mx.controls.Alert;
  12.             import com.demo.fr.User;
  13.             import com.demo.fr.frServices;
  14.             import mx.styles.StyleManager;
  15.            
  16.            
  17.             //1表示以可视化组件方式访问过程服务器。
  18.               //2表示以编程方式访问过程服务器。
  19.             private var mode : int = 2;
  20.            
  21.             //调用相关的Remoting服务或模式。
  22.             private function callServer(fn : String):void
  23.             {               
  24.                 if(this.mode == 1)
  25.                 {
  26.                     switch(fn)
  27.                     {
  28.                         case "DisplayHellow":
  29.                             sampleRemoteObject.DisplayHellow();
  30.                             break;
  31.                         case "SayHellowWorld":
  32.                             sampleRemoteObject.SayHellowWorld(this.txtMessage.text);
  33.                             break;                       
  34.                         case "GetUsers":
  35.                             sampleRemoteObject.GetUsers();
  36.                             break;
  37.                     }
  38.                 }
  39.                 else
  40.                 {
  41.                     var fr : frServices = new frServices();   
  42.                     this.addEventListener(frServices.Event_KEY_Fault,onRemoteFault2);
  43.                    
  44.                     switch(fn)
  45.                     {
  46.                         case "DisplayHellow":
  47.                             fr.addEventListener(frServices.Event_KEY_Success_DisplayHellow,onRemoteResult2);
  48.                             fr.call_DisplayHellow();
  49.                             break;
  50.                         case "SayHellowWorld":
  51.                             fr.addEventListener(frServices.Event_KEY_Success_SayHellowWorld,onRemoteResult2);
  52.                             fr.call_SayHellowWorld(this.txtMessage.text);
  53.                             break;                       
  54.                         case "GetUsers":
  55.                             fr.addEventListener(frServices.Event_KEY_Success_GetUsers,onRemoteResult2);
  56.                             fr.call_GetUsers();
  57.                             break;
  58.                     }
  59.                 }
  60.             }
  61.            
  62.            
  63.             //当Remoting服务调用成功的回调函数(控件调用)。
  64.             private function onRemoteResult(event:ResultEvent) : void
  65.             {
  66.                 this.remoteSuccessHandler(event.result,event.currentTarget.name);               
  67.             }
  68.            
  69.             //当Remoting服务调用失败的回调函数(控件调用)。
  70.             private function onRemoteFault(event:FaultEvent) : void
  71.             {
  72.                 this.remoteFault(event.fault.toString());
  73.             }       
  74.            
  75.             //当Remoting服务调用成功的回调函数(代码实现)。
  76.             private function onRemoteResult2(event : CUEvent):void
  77.             {
  78.                 this.remoteSuccessHandler(event.Sender,event.CurrentTargetName);
  79.             }

  81.             //当Remoting服务调用失败的回调函数(代码实现)。
  82.             private function onRemoteFault2(event : CUEvent) : void
  83.             {
  84.                 this.remoteFault(event.Sender.toString());
  85.             }       
  86.            
  87.             //当Remoting服务调用成功的处理。
  88.             private function remoteSuccessHandler(data : Object,fn : String):void
  89.             {
  90.                 switch(fn)
  91.                 {
  92.                     case "DisplayHellow":
  93.                         Alert.show(data as String,"DisplayHellow");
  94.                         break;
  95.                     case "SayHellowWorld":
  96.                         Alert.show(data as String,"SayHellowWorld");
  97.                         break;
  98.                     case "GetUsers":
  99.                         var userList : ArrayCollection = data as ArrayCollection;
  100.                         this.dgUsers.dataProvider = userList;
  101.                         break;
  102.                 }
  103.             }
  104.            
  105.             //当Remoting服务调用失败的处理。
  106.             private function remoteFault(desc:String):void
  107.             {
  108.                 Alert.show(desc,"Remoting调用出错");
  109.             }           

  111.            
  112.             //清空DataGrid中的数据。
  113.             private function clearUsers() : void
  114.             {
  115.                 this.dgUsers.dataProvider = null;
  116.             }
  117.            
  118.             //链接到本人的博客。
  119.             private function getURL():void
  120.             {
  121.                 flash.net.navigateToURL(new URLRequest("http://mrhgw.cnblogs.com"));
  122.             }   
  123.            
  124.         ]]>
  125.     </mx:Script>   
  126.    
  127.     <mx:RemoteObject id="sampleRemoteObject"
  128.         destination="fluorine"
  129.         source="Hxw.Demo.FlashRemoting.Hellow"
  130.         showBusyCursor="true">
  131.        
  132.       <!--这里是.NET中的方法，name = 方法名 -->     
  133.         <mx:method name="DisplayHellow" result="onRemoteResult(event)" fault="onRemoteFault(event)"/>
  134.         <mx:method name="SayHellowWorld" result="onRemoteResult(event)" fault="onRemoteFault(event)"/>
  135.         <mx:method name="GetUsers" result="onRemoteResult(event)" fault="onRemoteFault(event)"/>       
  136.     </mx:RemoteObject>
  137.     <mx:Panel layout="absolute" title="Flash Remoting Demo" fontSize="25" right="19" left="19" bottom="67" top="20">
  138.         <mx:TitleWindow x="28" y="29" width="290" height="116" layout="absolute" title="Display Hellow World" fontSize="15">
  139.             <mx:Button x="10" y="21" label="Call" id="btDisplayHellow" width="120" fontSize="15" click="callServer('DisplayHellow');"/>
  140.         </mx:TitleWindow>
  141.         <mx:TitleWindow layout="absolute" title="Say Hellow World" top="168" bottom="30" left="28" width="290" fontSize="15">
  142.             <mx:TextInput x="10" y="30" width="232" id="txtMessage" fontSize="13"/>
  143.             <mx:Button x="10" y="76" label="Call" id="btSayHellowWorld" width="120" fontSize="15" click="callServer('SayHellowWorld')"/>
  144.             <mx:Label x="10" y="0" text="Name：" fontSize="13" fontWeight="bold"/>
  145.         </mx:TitleWindow>
  146.         <mx:TitleWindow layout="absolute" title="Get Users" left="340" right="34" bottom="30" top="29" fontSize="15">
  147.             <mx:Button x="10" y="21" label="Call" id="btGetUser" width="120" fontSize="15" click="callServer('GetUsers')"/>
  148.             <mx:DataGrid id="dgUsers" fontSize="13" right="10" left="10" top="65" bottom="10">
  149.                 <mx:columns>
  150.                     <mx:DataGridColumn headerText="姓名" dataField="Name"/>
  151.                     <mx:DataGridColumn headerText="性别" dataField="Sex"/>
  152.                     <mx:DataGridColumn headerText="年龄" dataField="Age"/>
  153.                 </mx:columns>
  154.             </mx:DataGrid>
  155.             <mx:Button x="148" y="21" label="Clear" id="btClear" width="120" fontSize="15" click="clearUsers()"/>
  156.         </mx:TitleWindow>
  157.     </mx:Panel>
  158.     <mx:HRule right="10" left="10" bottom="44" height="10"/>
  159.     <mx:LinkButton label="Powered by Hxw([url]http://mrhgw.cnblogs.com[/url])" fontSize="15" fontStyle="italic" right="45" bottom="8" click="getURL();"/>
  160.    
  161. </mx:Application>
复制代码
5. 注意。


        在MXML Application的代码中，有代码：private var mode : int = 2;mode值为1表示以可视化组件方式访问远程服务器；mode值为2表示以编程方式访问远程服务器。

三. 结束语。

    flex 3 + .net开发flash Remoting本系列文章至此结束，如有谬误敬请指正，欢迎一起学习交流。（文/有容乃大）

四. Demo下载。

    ASP.NET服务器端代码及Flex客户端代码下载：
flex 3 + .net开发flash Remoting四 --- 完整代码及Demo下载
赞助商
赞助商
TOP
返回列表